#!/usr/bin/perl -ws
#
# hex2bin.pl
#
# This script converts hex number(s) to binary. and prints out each digit xxxx.
# You can ask to reverse bits and digits in the output
# You can change the separate character by reassigning the $char variable!
# e.g.:
# % ./hex2bin.pl -no_revb -no_revd -no_verbose 06d1a440c 0ffc
# 0000 0110 1101 0001 1010 0100 0100 0000 1100
# 0000 1111 1111 1100

# Run hex2bin.pl -h to see the options
#
# Last modified:  Wed Aug 21 14:35:03 SGT 2002
# Author:         Stas Bekman <stas@stason.org>
#

use strict;
use vars qw($h $no_revb $no_revd $no_verbose);

$0 =~ s|^.*/||;        # cut the basename of the command

# Diagnostic part...
if (!@ARGV || $h) {
    die <<EOI
\tConvert Hex Number(s) to Binary 
\nUsage:
\t $0 [-options] hex_number(s)
options:
   -h           You read me now
   -no_revb	DON'T Reverse bits in binary number		
   -no_revd	DON'T Reverse digits in hex number before conversion		
   -no_verbose  Suppress verbose output
	
[Default settings]: REVERSE bits in binary number, REVERSE digits in hex number
\n
EOI

}

# Get the numbers
my @hex = @ARGV;

# Define the separation character between each binary number
my $char = " ";

# Verbose output
unless ($no_verbose) {
    print $no_revb
        ?  "Normal Order of bits in binary number\n" 
        : "Reverse Order of bits in binary number\n";
    print $no_revd
        ?  "Normal Order of digits in hex number before conversion\n"
        : "Reverse Order of digits in hex number before conversion\n";
}

for (@hex) {
    my @digits = split //;
    @digits = reverse @digits if !$no_revd;
    for (@digits) {
        hex2bin($_);
    }
    print "\n";
}

sub hex2bin {
    my ($digit) = shift;
    print $no_revb
        ? unpack("B4", pack("H", $digit))
        : substr(unpack("b8", pack("H", $digit)), -4);
    print "$char";
}